Help with a Simple file transfer from a client to the host to send 2 text files.

[Chris80194]

Client file code

Code: QB64 [Select]

1. ' Client computer: Sends the file
2.  
3. 'INPUT "Enter a port number to broadcast on: ", port$
4. port$ = "12345" 'comment out demo code
5.  
6. 'INPUT "Enter the IP number to connect to: ", ipnum$
7. ipnum$ = "192.168.3.208" 'comment out demo code
8.  
9. wconnect$ = "TCP/IP:" + port$ + ":" + ipnum$
10.  
11. 'INPUT "Enter the name of a file to send: ", s$
12. 's$ = "Mileage.csv" 'comment out demo code
13. 't$ = "TripLog.csv"
14. S$ = "test2."
15. T$ = "test1."
16.  
17. PRINT "try to connect to Station " + wconnect$
18. PRINT "This Station IP is " + GetLocalIP$
19. PRINT "Send Files " + S$ + " " + T$
20. client = _OPENCLIENT(wconnect$)
21. IF client = 0 THEN PRINT "Could not connect!": END
22.  
23. PRINT "Sending " + S$ + "..."
24. PRINT #client, S$
25. OPEN S$ FOR BINARY AS #2
26. size& = LOF(2)
27. PRINT #client, size&
28. BufferSize& = 1024
29. BytesPerSecond& = 1048576
30. Buffer$ = SPACE$(BufferSize&)
31. FOR o& = 1 TO size& STEP BufferSize&
32.     IF o& + BufferSize& - 1 > size& THEN Buffer$ = SPACE$(size& - o& + 1)
33.     GET #2, , Buffer$
34.     PUT #client, , Buffer$
35.     _DELAY BufferSize& / BytesPerSecond&
36.     PRINT ".";
37. NEXT
38. PRINT 'new line
39. CLOSE #2
40. 'CLOSE #client
41. PRINT "File " + S$ + " sent successfully!"
42.  
43. PRINT "Sending " + T$ + "..."
44. PRINT #client, T$
45. OPEN T$ FOR BINARY AS #2
46. size& = LOF(2)
47. PRINT #client, size&
48. BufferSize& = 1024
49. BytesPerSecond& = 1048576
50. Buffer$ = SPACE$(BufferSize&)
51. FOR o& = 1 TO size& STEP BufferSize&
52.     IF o& + BufferSize& - 1 > size& THEN Buffer$ = SPACE$(size& - o& + 1)
53.     GET #2, , Buffer$
54.     PUT #client, , Buffer$
55.     _DELAY BufferSize& / BytesPerSecond&
56.     PRINT ".";
57. NEXT
58. PRINT 'new line
59. CLOSE #2
60. CLOSE #client
61. PRINT "File " + T$ + " sent successfully!"
62.  
63. FUNCTION GetLocalIP$
64.     SHELL _HIDE "cmd /c ipconfig > IPconfig.tmp"
65.     A = FREEFILE
66.     OPEN "IPconfig.tmp" FOR INPUT AS #A
67.     DO
68.         LINE INPUT #A, ipline$
69.         IF UCASE$(LEFT$(LTRIM$(ipline$), 4)) = "IPV4" THEN
70.             GetLocalIP$ = MID$(ipline$, INSTR(ipline$, ":") + 2)
71.             IF GetLocalIP$ = "127.0.0.1" THEN GOTO 77
72.             CLOSE #A
73.             KILL "IPconfig.tmp" 'kill the messenger?
74.             EXIT DO
75.            77
76.         END IF
77.     LOOP UNTIL EOF(1)
78.  
79. END FUNCTION
80.  

The above code acts like it connects and sends the files named in the code just simple text files

The Host connects and spits out Zero and Zero in 2 columns and wont return to :1 to start over and wait, so it could receive another file if another one would be sent.

Code: QB64 [Select]

1. ' Host Computer: Receives the file
2.  
3. 'INPUT "Enter the port number to listen on: ", port$
4. 1
5. COLOR 7, 4
6. CLS
7. CLOSE
8.  
9. port$ = "12345" 'comment out demo code
10.  
11. v$ = "TCP/IP:" + port$
12. host = _OPENHOST(v$)
13. TTime$ = DATE$ + "_" + LEFT$(TIME$, 2) + "." + MID$(TIME$, 4, 2) + "." + RIGHT$(TIME$, 2) + ".TXT"
14. Path$ = "C:\Users\Chris\Downloads\Files"
15. Receive$ = Path$ + TTime$
16. Logging$ = Path$ + "IPLOG.txt"
17. LOCATE 10, 27: PRINT "Esc to shut down host."
18. IF host <> 0 THEN LOCATE 12, 20: PRINT GetLocalIP$ + ":" + port$; " You are the host."
19. LOCATE 11, 20: PRINT "Path to save to is " + Path$
20.  
21. DO
22.     keyed$ = INKEY$
23.     IF keyed$ = CHR$(27) THEN SYSTEM
24.     newclient = _OPENCONNECTION(host)
25.     IF newclient <> 0 THEN
26.         PRINT "Another computer has connected! "
27.         B = FREEFILE
28.         OPEN Logging$ FOR APPEND AS #B
29.         IP$ = _CONNECTIONADDRESS(newclient)
30.         PRINT IP$ + " has joined." ' displayed to Host only
31.         PRINT #B, IP$, TTime$ ' print info to a log file
32.         CLOSE B
33.  
34.         DO
35.             INPUT #newclient, s$
36.         LOOP UNTIL EOF(newclient) = 0
37.  
38.         '        DO
39.         '       INPUT #newclient, size&
40.         '      LOOP UNTIL EOF(newclient) = 0
41.  
42.         PRINT "Downloading " + s$ + "... To " + Receive$
43.         C = FREEFILE
44.         PRINT "--------------------------------"
45.         PRINT newclient
46.         PRINT EOF(newclient)
47.         PRINT s$
48.         PRINT size&
49.         PRINT "--------------------------------"
50.  
51.         OPEN Receive$ + s$ FOR OUTPUT AS #C
52.         filesize& = 0
53.         DO
54.             GET #newclient, , UT$
55.             filesize& = filesize& + LEN(UT$)
56.             IF LEN(t$) THEN PRINT #C, , UT$: PRINT ".";
57.             _DELAY 0.01
58.             PRINT filesize&, size&
59.             '        LOOP UNTIL filesize& = size&
60.         LOOP
61.         PRINT 'newline
62.         CLOSE #B
63.         CLOSE #newclient
64.         PRINT s$ + Receive$ + s$ + " successfully!"
65.     END IF
66. LOOP
67.  
68. DO
69.     keyed$ = INKEY$
70.     IF keyed$ = CHR$(27) THEN SYSTEM
71.     newclient = _OPENCONNECTION(host)
72.     IF newclient <> 0 THEN
73.         PRINT "Another computer has connected! "
74.         B = FREEFILE
75.         OPEN Logging$ FOR APPEND AS #B
76.         IP$ = _CONNECTIONADDRESS(newclient)
77.         PRINT IP$ + " has joined." ' displayed to Host only
78.         PRINT #B, IP$, TTime$ ' print info to a log file
79.         CLOSE B
80.  
81.         DO
82.             INPUT #newclient, t$
83.         LOOP UNTIL EOF(newclient) = 0
84.  
85.         '        DO
86.         '       INPUT #newclient, size&
87.         '      LOOP UNTIL EOF(newclient) = 0
88.  
89.         PRINT "Downloading " + t$ + "... To " + Receive$
90.         C = FREEFILE
91.         PRINT "--------------------------------"
92.         PRINT newclient
93.         PRINT EOF(newclient)
94.         PRINT t$
95.         PRINT size&
96.         PRINT "--------------------------------"
97.  
98.         OPEN Receive$ + t$ FOR OUTPUT AS #C
99.         filesize& = 0
100.         DO
101.             GET #newclient, , UT$
102.             filesize& = filesize& + LEN(UT$)
103.             IF LEN(t$) THEN PRINT #C, , UT$: PRINT ".";
104.             _DELAY 0.01
105.             PRINT filesize&, size&
106.             '        LOOP UNTIL filesize& = size&
107.         LOOP
108.         PRINT 'newline
109.         CLOSE #B
110.         CLOSE #newclient
111.         PRINT t$ + Receive$ + t$ + " successfully!"
112.     END IF
113. LOOP
114. GOTO 1
115.  
116. FUNCTION GetLocalIP$
117.     SHELL _HIDE "cmd /c ipconfig > IPconfig.tmp"
118.     A = FREEFILE
119.     OPEN "IPconfig.tmp" FOR INPUT AS #A
120.     DO
121.         LINE INPUT #A, ipline$
122.         IF UCASE$(LEFT$(LTRIM$(ipline$), 4)) = "IPV4" THEN
123.             GetLocalIP$ = MID$(ipline$, INSTR(ipline$, ":") + 2)
124.             IF GetLocalIP$ = "127.0.0.1" THEN GOTO 77
125.             CLOSE #A
126.             KILL "IPconfig.tmp" 'kill the messenger?
127.             EXIT DO
128.            77
129.         END IF
130.     LOOP UNTIL EOF(1)
131.  
132. END FUNCTION
133.  

This looks like it should be a simple fix but TCP was not around when I leaned Basic code.
Thank you for your help.

Ps. I would like a snip of code to verify if a certain IP or maybe domain name can be reached before making an automated attempt in the client side.
Thanks again

[Petr]

I think, you search IF _CONNECTED (connectionhandle&)? I have a TCP / IP transmission program somewhere, but I have to find it first

[FellippeHeitor]

I'm still to give your code a more thorough read but one thing caught my eye at a first glance: don't use PRINT and INPUT with TCP/IP. Use GET/PUT. I'll get back to you later after I've had time to analyse it further.

[Chris80194]

Petr How would I use  IF _CONNECTED (connectionhandle&)
Just like that or do I need to add a loop of some kind?  Thanks


FellippeHeitor GET/PUT ill have to change those into the program.... I think the print and input was in the original code snippet that I found.  Thanks

Please keep in touch with any ideas and updates, Thanks.

[Petr]

Hi. I found the program, which use it:

Code: QB64 [Select]

1. 'NETWORK File transfer demo program.
2.  
3.  
4. DIM SHARED Host AS LONG, Client AS LONG
5. DIM InFile AS STRING * 128, OutFile AS STRING * 128, ok AS STRING * 2
6. CONST PACKET = 4096
7.  
8.  
9.  
10. I_am = Network("localhost")
11. InFile$ = "Z:\op_copy.avi" '             1899 megabytes file                         Both this strings are always 128 bytes long (DIM)
12. OutFile$ = "E:\copy.wav" '    copy send via network to this client place
13.  
14.  
15. SELECT CASE I_am
16.     CASE 1 'HOST   -    in this demo HOST send FILE to client
17.         _TITLE "Host"
18.         IF _FILEEXISTS(InFile$) THEN OPEN InFile$ FOR BINARY AS #1 ELSE BEEP: PRINT "File for transfer (source) not found"; InFile$: END
19.         PRINT "Sending File name and file size...("; RTRIM$(InFile$); " and"; LOF(1); LTRIM$(")")
20.         res$ = InFile$ + MKL$(LOF(1)) '                       size is set by DIM for InFile$ + 4 bytes LONG value for file size
21.         PUT #Host, , res$ '                                   send file name and file size
22.         _DELAY .005
23.         PRINT "Waiting for confirmation of the name and size ..."
24.  
25.         ok$ = Transfer$(Host, 2)
26.         IF ok$ = "OK" THEN PRINT "Name and size transferred correctly." ELSE END
27.         ok$ = ""
28.  
29.         PRINT "Uploading file..."
30.  
31.         zbyva& = LOF(1) '                               This variable in begin is the same value as uploaded file size
32.         DO WHILE zbyva& > 0 '                           Block for transport is 10 000 000 bytes, upload until all bytes are send
33.             IF zbyva& > PACKET THEN Block$ = SPACE$(PACKET) ELSE Block$ = SPACE$(zbyva&)
34.             zbyva& = zbyva& - PACKET
35.             GET #1, , Block$ '
36.             PUT #Host, , Block$
37.             IF LOF(1) > PACKET THEN DO UNTIL Transfer$(Host, 2) = "OK": LOOP '   wait for confirmation, that all bytes from 10 000 000 bytes packet comming to CLIENT.
38.         LOOP '                                           THEN is next packet send.
39.  
40.         PRINT "Waiting for confirmation FILE SIZE"
41.         message$ = Transfer$(Host&, 4) '                 It checks if the created and written file is the same size as the source file
42.         IF CVL(message$) = LOF(1) THEN PRINT "Image transferred correctly. ": END ELSE PRINT "Post:"; LOF(1); "bytes, but received"; CVL(message$); "bytes!"
43.     CASE 2 'CLIENT - in this demo receive and write file
44.         _TITLE "Client"
45.  
46.         PRINT "Receiving info about file..."
47.         file$ = Transfer$(Client, 132)
48.         FileName$ = LTRIM$(LEFT$(file$, 128)) ' maximal file name lenght is set by DIM to 128 bytes in this program
49.         FileSize& = CVL(RIGHT$(file$, 4))
50.         PRINT "File in transfer: "; RTRIM$(FileName$)
51.         PRINT "File size (bytes): "; FileSize&
52.  
53.         PRINT "Confirm file name and file size ..."
54.         ok$ = "OK"
55.         PUT #Client, , ok$
56.  
57.  
58.         'if filesize is smaller than 10 000 000 bytes, use standard way without blocks
59.         IF FileSize& < PACKET THEN
60.             Content$ = Transfer$(Client, FileSize&)
61.  
62.             OPEN RTRIM$(OutFile$) FOR OUTPUT AS #2: CLOSE #2 '     create new clear file - in this case named differently, but in real network use File_Name$, here its for localhost test in the same directory
63.             OPEN RTRIM$(OutFile$) FOR BINARY AS #2 '               write binary data to file
64.             PRINT "Writing file..."
65.             PUT #2, , Content$
66.             Writed_Size& = LOF(2)
67.             CLOSE #2
68.             confirm$ = MKL$(Writed_Size&) '                        client post WRITED SIZE as control back to Host
69.             PUT #Client&, , confirm$
70.             IF Writed_Size& = FileSize& THEN PRINT "Transfer OK!"
71.  
72.  
73.         ELSE 'if file is bigger than 10 000 000  bytes, use blocks:
74.             OPEN RTRIM$(OutFile$) FOR OUTPUT AS #2: CLOSE #2 '     create new clear file - in this case named differently, but in real network use File_Name$, here its for localhost test in the same directory
75.             OPEN RTRIM$(OutFile$) FOR BINARY AS #2 '               write binary data to file
76.             zbyva& = FileSize&
77.  
78.             IF FileSize& > 0 THEN '                                For percentage transfer calculation
79.                 IF FileSize& MOD PACKET THEN TB = 1
80.                 TotalBlocks = INT(FileSize& / PACKET) + TB
81.             END IF
82.             Ln = CSRLIN
83.             'in every loop in transmitted one 10 000 000 bytes lenght block
84.             DO WHILE zbyva& > 0
85.                 IF zbyva& > PACKET THEN Block$ = Transfer$(Client, PACKET) ELSE Block$ = Transfer$(Client, zbyva&)
86.                 zbyva& = zbyva& - PACKET
87.                 PUT #2, , Block$
88.                 ok$ = "OK"
89.                 PUT #Client, , ok$ '                                send confirmation, that this block is writed and can be send next by HOST
90.  
91.                 Block = Block + 1
92.                 Block$ = ""
93.                 perc = INT(100 * (Block / TotalBlocks))
94.                 IF oldperc <> perc THEN oldperc = perc: LOCATE Ln,: PRINT "Block "; Block; "/"; TotalBlocks; "("; perc; "%)    "
95.             LOOP
96.             _DELAY 2
97.             Writed_Size& = LOF(2)
98.             confirm$ = MKL$(Writed_Size&) '                          client post WRITED SIZE as control back to Host
99.             PUT #Client&, , confirm$
100.             IF Writed_Size& = FileSize& THEN PRINT "Transfer OK!"
101.         END IF
102. END SELECT
103. CLOSE #2, #1, #Host&, #Client&
104. END
105.  
106.  
107. FUNCTION Transfer$ (channel AS LONG, lenght)
108.     SHARED prubeh
109.     Transfer$ = ""
110.     DO
111.         GET #channel&, , T$
112.         IF LEN(T$) THEN Transfer$ = Transfer$ + T$
113.         '  IF _CONNECTED(channel&) = 0 THEN PRINT "Connection failure.": END
114.     LOOP WHILE LEN(Transfer$) < lenght
115. END FUNCTION
116.  
117. FUNCTION Network (IP AS STRING)
118.     Client& = _OPENCLIENT("TCP/IP:3455:" + LTRIM$(IP$))
119.     IF Client& THEN
120.         Network = 2 'client
121.     ELSE
122.         PRINT "No host found"
123.         _DELAY 1
124.         Client& = _OPENHOST("TCP/IP:3455")
125.         IF Client& THEN
126.             PRINT "Host created!"
127.             DO
128.                 i& = _KEYHIT
129.                 IF i& = 27 THEN EXIT FUNCTION
130.                 Host& = _OPENCONNECTION(Client&)
131.             LOOP UNTIL Host&
132.             Network = 1
133.         END IF
134.     END IF
135. END FUNCTION
136.  

Function Transfer$ show you _CONNECTED using.

[Chris80194]

ill try it out thanks

[Chris80194]

Is that both the Client and Host?
line 10 looks like where I set either or but I am not sure what the context should be?

[Petr]

Hi. Function NETWORK in my program automatically return what current computer is. 1 for host, 2 for client. Program so as is,  is writed for both sides.

[Pete]

Hi. Function NETWORK in my program automatically return what current computer is. 1 for host, 2 for client. Program so as is,  is writed for both sides.

What a coincidence. My NETWORK sub designates the host and client computers by numbers 1 and 2 as well; however, I use network mapping instead of tcp/ip to network my office software. I have never tried that on Win 10 but I was able to connect with Visa, XP, and Win 7. That helped, as I did not have to update all my office computers as I bought new ones. I found it necessary to use the LOCK statement to prevent multiple users from accessing the same files at the same time.

Pete

[Craz1000]

any way to get these file transfer as a sub for example i have been trying for hours to no avail.

Call SendFile(File$) and Call GetFile(File$)

connection is already established as #Connection on server and client programs

[Petr]

Craz1000: It works well for me. Did you run the program twice to simulate HOST and CLIENT on the same pc?

[Pete]

Maybe anti-virus software interfering? I vaguely recall having to disable ZoneAlarm or some sort of modification when I networked my office computers.

Pete

[Craz1000]

Now that i am finally at my desk. I am trying to put together a library of TCP functions and subs to do various things to be $INCLUDEd in future programs. One of the things i want to add is a file transfer support. What I have on here was where I left off last night. I did copy the entire code that was posted and changed some things to get it to work this way, but nothing is transferred. At the point I left off I was grabbing at straws and the transfer code looks nothing like what was posted above at this point. But you can get the basic idea at what i am trying to do with this file.

Code: QB64 [Select]

1. DIM SHARED BLOCK AS STRING * 4096
2. DIM SHARED PACKET
3. PACKET = 4096
4.  
5.  
6.  
7. SUB GETFILE (FILE$)
8.     OPEN FILE$ FOR OUTPUT AS #2
9.     CLOSE #2
10.     OPEN FILE$ FOR BINARY AS #2
11.     PRINT "Writing file..."
12.  
13.     CALL SENDMSG("READY")
14.     DO
15.         IF CONNECTION THEN
16.             BLOCK$ = ""
17.             GET #CONNECTION, , BLOCK$
18.             PRINT BLOCK$
19.             IF RTRIM$(BLOCK$) <> ":EOF" THEN PUT #2, , BLOCK$
20.             CALL SENDMSG("NEXT")
21.         END IF
22.     LOOP UNTIL RTRIM$(BLOCK$) = ":EOF"
23.     CLOSE #2
24.     PRINT "TRANSFER COMPLETE"
25. END SUB
26.  
27. SUB SENDFILE (FILE$)
28.     IF _FILEEXISTS(FILE$) THEN
29.         OPEN FILE$ FOR BINARY AS #1
30.     ELSE
31.         PRINT "File for transfer (source) not found"; FILE$
32.         EXIT SUB
33.     END IF
34.  
35.     IF WAITFORREPLY$ = "READY" THEN
36.         PRINT "Uploading file..."
37.  
38.         DO
39.             GET #1, , BLOCK$
40.             PUT #CONNECTION, , BLOCK$
41.             '    PRINT BLOCK$
42.             DO
43.             LOOP UNTIL WAITFORREPLY$ = "NEXT"
44.             BLOCK$ = ""
45.         LOOP UNTIL EOF(1)
46.         CALL SENDMSG(":EOF")
47.         PRINT "TRANSFER COMPLETE"
48.         CLOSE #1
49.     END IF
50. END SUB
51.  
52. FUNCTION Transfer$ (LENGTH)
53.     Transfer$ = ""
54.     DO
55.         GET #CONNECTION, , T$
56.         Transfer$ = Transfer$ + T$
57.     LOOP WHILE LEN(Transfer$) < LENGTH
58. END FUNCTION
59.  
60.  
61. SUB SENDMSG (MSG$)
62.     MSG$ = UCASE$(MSG$)
63.     PUT #CONNECTION, , MSG$
64. END SUB
65.  
66. FUNCTION WAITFORREPLYNUM
67.     DO
68.         GET #CONNECTION, , RPL
69.     LOOP UNTIL RPL <> 0
70.     WAITFORREPLYNUM = RPL
71. END FUNCTION
72.  
73. FUNCTION WAITFORREPLYRAW$
74.     DO
75.         GET #CONNECTION, , RPL$
76.     LOOP UNTIL RPL$ <> ""
77.     WAITFORREPLYRAW$ = RPL$
78. END FUNCTION
79.  
80.  
81. FUNCTION WAITFORREPLY$
82.     T! = TIMER
83.     DO
84.         GET #CONNECTION, , RPL$
85.     LOOP UNTIL RPL$ <> "" OR TIMER > T! + 3
86.  
87.     IF TIMER > T! + 3 THEN
88.         WAITFORREPLY$ = "TIMEOUT"
89.     ELSE
90.         WAITFORREPLY$ = RTRIM$(RPL$)
91.     END IF
92. END FUNCTION
93.  

[Pete]

I noticed you did not DIM T$.

[Craz1000]

I got it working tried basing it on the code above again.

Code: QB64 [Select]

1.  
2.  
3.  
4. SUB GETFILE (FILE$)
5.     PACKET = 4096
6.     PRINT "Receiving info about file..."
7.     SENDMSG ("INFO")
8.     FILESIZE$ = LTRIM$(WAITFORREPLY$)
9.     FILESIZE& = VAL(FILESIZE$)
10.     PRINT "File in transfer: "; FILE$
11.     PRINT "File size (bytes): "; FILESIZE&
12.     SENDMSG ("OK")
13.  
14.     IF FILESIZE& < PACKET THEN
15.         BLOCK$ = Transfer$(FILESIZE&)
16.  
17.         OPEN FILE$ FOR OUTPUT AS #2: CLOSE #2
18.         OPEN RTRIM$(FILE$) FOR BINARY AS #2
19.         PRINT "Writing file..."
20.         PUT #2, , BLOCK$
21.         WROTE& = LOF(2)
22.         CLOSE #2
23.         IF WROTE& = FILESIZE& THEN PRINT "Transfer OK!"
24.     ELSE
25.         OPEN FILE$ FOR OUTPUT AS #2: CLOSE #2
26.         OPEN RTRIM$(FILE$) FOR BINARY AS #2
27.         zbyva& = FILESIZE&
28.  
29.         DO WHILE zbyva& > 0
30.             IF zbyva& > PACKET THEN BLOCK$ = Transfer$(PACKET) ELSE BLOCK$ = Transfer$(zbyva&)
31.             zbyva& = zbyva& - PACKET
32.             PUT #2, , BLOCK$
33.             SENDMSG ("OK")
34.             BLOCK$ = ""
35.         LOOP
36.         _DELAY 2
37.         WROTE& = LOF(2)
38.         CLOSE #2
39.         IF WROTE& = FILESIZE& THEN PRINT "Transfer OK!"
40.     END IF
41. END SUB
42.  
43. SUB SENDFILE (FILE$)
44.     PACKET = 4096
45.     IF _FILEEXISTS(FILE$) THEN OPEN FILE$ FOR BINARY AS #1
46.     PRINT "Sending File name and file size...("; FILE$; " and"; LOF(1); ")"
47.     IF WAITFORREPLY$ = "INFO" THEN SENDMSG STR$((LOF(1)))
48.  
49.     _DELAY .005
50.  
51.     PRINT "Waiting for confirmation of the name and size ..."
52.  
53.     IF WAITFORREPLY$ = "OK" THEN
54.         PRINT "Uploading file..."
55.  
56.         zbyva& = LOF(1)
57.         DO WHILE zbyva& > 0
58.             IF zbyva& > PACKET THEN Block$ = SPACE$(PACKET) ELSE Block$ = SPACE$(zbyva&)
59.             zbyva& = zbyva& - PACKET
60.             GET #1, , Block$ '
61.             PUT #CONNECTION, , Block$
62.             IF LOF(1) > PACKET THEN DO UNTIL WAITFORREPLY$ = "OK": LOOP
63.         LOOP
64.     END IF
65.     CLOSE #1
66. END SUB
67.  
68.  
69. FUNCTION Transfer$ (LENGTH&)
70.     Transfer$ = ""
71.     DO
72.         GET #CONNECTION, , T$
73.         IF LEN(T$) THEN Transfer$ = Transfer$ + T$
74.         '  IF _CONNECTED(channel&) = 0 THEN PRINT "Connection failure.": END
75.     LOOP WHILE LEN(Transfer$) < LENGTH&
76. END FUNCTION
77.  
78.  
79. SUB SENDMSG (MSG$)
80.     MSG$ = UCASE$(MSG$)
81.     PUT #CONNECTION, , MSG$
82. END SUB
83.  
84.  
85. FUNCTION WAITFORREPLY$
86.     T! = TIMER
87.     DO
88.         GET #CONNECTION, , RPL$
89.     LOOP UNTIL RPL$ <> "" OR TIMER > T! + 3
90.  
91.     IF TIMER > T! + 3 THEN
92.         WAITFORREPLY$ = "TIMEOUT"
93.     ELSE
94.         WAITFORREPLY$ = RTRIM$(RPL$)
95.     END IF
96. END FUNCTION
97.  
98.